Sep 01

Sneak preview about DORM, The Delphi ORM

Design Patterns, Programming, RTTI 18 Comments »

My yesterday post about this busy time, have raised some interest about DORM, the Delphi ORM.

So, also if I still haven’t released any files, wish to expose some internals about DORM.

DORM is an implementation of the DataMapper design pattern written having Hibernate in mind.

It’s completely unit tested and have the following features:

  • External file mapping. (JSON format)
  • Persistence ignorance (every TObject can be persisted)
  • Support for One-One and One-Many relations (still no many-many)
  • Support for LazyLoading (you can enable§/disable lazyloading by file or by code by per-basis needs)
  • Support for IdentityMap
  • Support for custom “finder” (you can still use complex SQL if you want)
  • Complete support for CRUD
  • Transactions
  • Built in logging system to log *EVERY* sql or action performed by the framework
  • Opened to multiple data access strategies (interfaced based, not inheritance based) for use with different database (now I’ve developed the firebird one using DBX)
  • Caching for RTTI (the TSession object have a single TRttiContext holding ALL metadata)

Code is still under heavely development.

Those are 2 test-method to show the use of DORM:

  1. TPerson = class(TObject)
  2. …
  3. property Phones: TdormCollection…. //implements IList
  4. end;
  5.  
  6. TPhone = classs(TObject)
  7. …
  8. end;
  9.  
  10. //and now the unit tests
  11.  
  12. procedure TTestDORMHasMany.Setup;
  13. begin
  14.   Session := TSession.Create;
  15.   Session.Configure(TStreamReader.Create('dorm.conf'));
  16. end;
  17.  
  18. procedure TTestDORMHasMany.TearDown;
  19. begin
  20.   Session.Free;
  21. end;
  22.  
  23. procedure TTestDORMHasMany.TestHasManyLazyLoad;
  24. var
  25.   p: TPerson;
  26.   t: TPhone;
  27.   guid: string;
  28. begin
  29.   p := TPerson.NewPersona;  //static method. Return a fully populated TPerson object
  30.   try
  31.     t := TPhone.Create;
  32.     p.Phones.Add(t);
  33.     Session.Save(p);
  34.     guid := p.guid;  //GUIDs, or other PK types, are generated automagically by DORM. Obviously there is a specific class loaded to do this specified in the dorm.conf file)
  35.   finally
  36.     Session.Commit;
  37.   end;
  38.   Session.StartTransaction;
  39.  
  40.   // Test with lazy load ON
  41.   Session.SetLazyLoadFor(TypeInfo(TPerson), 'Phones', true);
  42.   p := Session.Load(TypeInfo(TPerson), guid) as TPerson;
  43.   try
  44.     CheckEquals(0, p.Phones.Count);
  45.   finally
  46.     Session.Commit;
  47.   end;
  48.  
  49.   Session.StartTransaction;
  50.   // Test with lazy load OFF
  51.   Session.SetLazyLoadFor(TypeInfo(TPerson), 'Phones', false);
  52.   p := Session.Load(TypeInfo(TPerson), guid) as TPerson; // Without commit, AV becouse IdentityMap doesn't work properly
  53.   try
  54.     CheckEquals(1, p.Phones.Count); // Child objects are loaded
  55.   finally
  56.     Session.Commit;
  57.   end;
  58. end;
  59.  
  60. procedure TTestDORMHasMany.TestLoadHasMany;
  61. var
  62.   list: IList;
  63.   t, t1: TPhone;
  64.   p: TPerson;
  65.   guid: string;
  66. begin
  67.   p := TPerson.NewPersona;  //static method. Return a fully populated TPerson object
  68.   try
  69.     t := TPhone.Create;
  70.     t.Numero := '555-7765123';
  71.     t.Kind := 'Casa';
  72.     p.Phones.Add(t);
  73.  
  74.     t1 := TPhone.Create;
  75.     t1.Number := '555-7765123';
  76.     t1.Kind := 'Casa';
  77.     p.Phones.Add(t1);
  78.     Session.Save(p); // save Person and Phones
  79.     guid := p.guid;
  80.   finally
  81.     Session.Commit;
  82.   end;
  83.  
  84.   Session.StartTransaction;
  85.   p := Session.Load(TypeInfo(TPerson), guid) as TPerson;
  86.   try
  87.     CheckEquals(2, p.Phones.Count);
  88.   finally
  89.     Session.Commit;
  90.   end;
  91. end;

Mapping, contained in a file called “dorm.conf”, is similar to the following:

  1. {
  2.   "persistence": {
  3.     "database_adapter": "dorm.adapter.Firebird.TFirebirdPersistStrategy",
  4.     "database_connection_string":"127.0.0.1:C:\\MyProjects\\DORM\\experiments\\dorm.fdb",
  5.     "username": "sysdba",
  6.     "password":"masterkey"
  7.     },
  8.   "config": {
  9.     "package": "dorm.bo.Person",
  10.     "logger_class_name": "dorm.loggers.FileLog.TdormFileLog"
  11.   },      
  12.   "mapping":
  13.     {      
  14.       "TPerson":
  15.       {
  16.         "table": "people",
  17.         "id": {"name":"guid", "field":"guid", "field_type":"string", "size": 100, "default_value": ""},
  18.         "fields":[
  19.           {"name":"firstname", "field":"first_name", "field_type":"string", "size": 100},
  20.           {"name":"lastname", "field":"last_name", "field_type":"string", "size": 100},
  21.           {"name":"age", "field":"age", "field_type":"integer"},
  22.           {"name":"borndate", "field":"born_date", "field_type":"date"}
  23.           ],
  24.         "has_many":[{
  25.           "name": "Phones",
  26.           "class_name":"TPhone",
  27.           "child_field_name":"guid_person",
  28.           "lazy_load": false
  29.         }],
  30.         "has_one": {
  31.           "name": "car",
  32.           "class_name":"TCar",
  33.           "child_field_name":"guid_person"
  34.         }
  35.       },
  36.       "TPhone":
  37.       {
  38.         "table": "phones",
  39.         "id": {"name":"guid", "field":"guid", "field_type":"string", "size": 100, "default_value": ""},
  40.         "fields":[
  41.           {"name":"number", "field":"number", "field_type":"string", "size": 100},
  42.           {"name":"kind", "field":"kind", "field_type":"string", "size": 100},
  43.           {"name":"guid_person", "field":"guid_person", "field_type":"string", "size": 100}
  44.           ]
  45.       }
  46.     }
  47. }

The PODO (Plain Old Delphi Objects) can be binded to the VCL controls with a set of MediatingView (Model-GUI-Mediator Pattern) with an Observer mechanism to mantain things in synch.

Any comments? Someone interested?

Jun 12

Delphi Day 2010

Continuous Integration, Delphi 2010, Events, Programming, bit Time Software No Comments »

Also this year I was at Delphi Day with many others bit Time co-workers.
This year I did a speech about Continuous Integration and Unit Test with Delphi.

I showed some of the methodologies and tools that we used in bitTime for long and for whom we also offer training.

Many Delphi programmers and companies should consider adoption of this tecnique for do more and better with the same effort (and the same money).

The event was interesting and was also an opportunity to meet some of the Italian Delphi programmers with which to meet and exchange ideas.

Marco wrote a nice summary of the event in his blog.

May 17

My interview at PHP Day 2010 has been published

Continuous Integration, Programming, bit Time Software 2 Comments »

My interview at PHP Day 2010 has been published on php.html.it.

This is the link to the article.

This is the video on youtube.

The interview is only in italian language.

May 13

My speech at “PHP Day 2010″

Continuous Integration, Events 2 Comments »

This time a very fast post…
For the third year in a row, I will talk at the PHP Day in Italy organized, as usual, by the friends of GRUSP.

My speech will be about Continuous Integration and PHP, with a little introduction to Hudson.

This is the main conference website.
This is my speaker/speech page.

Enough fast? ;-)

May 06

A Simple start with MVP in Delphi for Win32, Part 2

Delphi 2010, Delphi Dependency Injection, Design Patterns, MVC, MVP, Uncategorized 2 Comments »

Some month ago I wrote a simple article about an MVP variant called PassiveView.
That example was very simple. Now I’ll present a more “advanced” version of that example.

The main problem with first example was the following method:

  1. procedure TfrmCalculatorView.FormCreate(Sender: TObject);
  2. begin
  3.   //Link controls with related interface
  4.   IFirstOperand := TGUIEdit.Create(EditFirstOp);
  5.   ISecondOperand := TGUIEdit.Create(EditSecondOp);
  6.   ICalcResult := TGUIEdit.Create(EditResult);
  7.   IOperators := TGUISelectableList.Create(ComboOperators);
  8.   IError := TGUIEdit.Create(EditError);
  9.  
  10.   //link view and presenter
  11.   FPresenter := TCalculatorPresenter.Create(Self); //<<– THIS IS THE BAD LINE
  12. end;

The “BAD” line links the View with the Presenter but it’s in the view code, so this is meaning that View KNOWS the presenter… and this is not a good thing becouse the view is not so “passive”.

In a more advanced (and complex) version the View should be completely ignorant about the class that implement the presenter and the service.

In the main dpr file now the code now looks like the following.

  1. var
  2.   MainPresenter: ICalculatorPresenter;
  3.   CalculatorView: TForm;
  4. begin
  5.   Application.Initialize;
  6.   Application.MainFormOnTaskbar := True;
  7.   //SETUP THE MAIN APPLICATION FORM FOR VCL PURPOSE
  8.   Application.CreateForm(TfrmCalculatorView, CalculatorView);  
  9.   //SETUP ALL THE LINKS BETWEEN THE MVP TRIAD
  10.   MainPresenter := TCalculatorPresenter.Create(CalculatorView as ICalculatorView, TCalculatorService.Create);
  11.   //LETS START!
  12.   Application.Run;
  13. end.

Now the presenter take care about all links between the MVP triad.

  1. constructor TCalculatorPresenter.Create(CalculatorView: ICalculatorView;
  2.   CalculatorService: ICalculatorService);
  3. begin
  4.   inherited Create;
  5.   FCalculatorService := CalculatorService;
  6.   FCalculatorView := CalculatorView;
  7.   FCalculatorView.SetPresenter(self);
  8.   InitView;  //does the links
  9. end;

There is another addition to the previous example. Now there is only one constructor in the presenter, and using dependency injection take 2 interface for the view and the service.

  1.     constructor Create(CalculatorView: ICalculatorView; CalculatorService: ICalculatorService);

Another plus is the possibility to open the same form a number of times without change the code for create it.

This is the GUI for this simple application.

3 instance of the same view with different presenter and service

3 instance of the same view with different presenter and service

As bonus, unit tests and mock object arent changed.

As usual the source code is here.

Apr 18

Delphi Stomp Client (with FreePascal support)

Delphi 2010, Message Oriented Middleware, STOMP 1 Comment »

Yes, I’ve just committed last version of DelphiStompClient, a STOMP client for Delphi 2010 (should works in 2007 and 2009 too) and FreePascal 2.4.

DelphiStompClient has been tested with Apache ActiveMQ 5.2 and 5.3 but should works with every STOMP compliant server.

You can find the code here, but if you need more info with example and other stuff, read entire article.

The FreePascal version is mantained by Daniel Gaspary.

Apr 08

New beta version for DataSnap Filters Compendium

DataSnap Filters Compendium, Delphi 2010 1 Comment »

I’ve been very busy lately with some Delphi related events here in Italy

so I havent too much time for my personal open source project. But now I’ve released new beta version for DSFC.

This release address a problem with the cypher filters.

Cypher filters arent completely compatible with the previuous version, so you need to rebuild the server and the client if you want to use this new version of DSFC.

There are one known issue:

  • Cannot have multiple connections in a client with the same filters but different cipher keys connecting to different servers.

Some users asked to me a little tutorial to setup a demo application with the cypher filters. Now there is a project group illustrating how do it.

There is also a new net speed test.

I’m waiting for some testers feedback comment before of 1.1 version.

As usual you can find the source code in the GoogleCode SVN repository

http://dsfc.googlecode.com

Happy testing!

Jan 06

A simple Dependency Injection Container for Delphi

Delphi 2010, Delphi Dependency Injection, Design Patterns 9 Comments »

As wikipedia says:

“Dependency injection (DI) in computer programming refers to the process of supplying an external dependency to a software component. It is a specific form of inversion of control where the concern being inverted is the process of obtaining the needed dependency. The term was first coined by Martin Fowler to describe the mechanism more clearly.”

Many of us have already read this historical article from Martin Fowler about dependency injection pattern, but actually there isn’t a real framework for implement dependency injection in Delphi.

There are already the following implementation for DI in Delphi

  • Emballo (work with pre-D2010 too, but the implementation require changes in the service classes. I really hate it)
  • Delphi Spring Framework (very nice, but still not realeased)

So, I decided to write my own simple DI framework.

You can find the code at google code project here: http://code.google.com/p/delphidicontainer/

This is the first public version and come with sample, documentation and unit tests.

Folow some sample code.

  1. program Test01;
  2. {$APPTYPE CONSOLE}
  3.  
  4. uses
  5.   SysUtils,
  6.   DIContainer in '..\..\src\DIContainer.pas',
  7.   ServiceTestObjectsU in '..\..\UnitTest\ServiceTestObjectsU.pas';
  8.  
  9. var
  10.   DIContainer: TDIContainer;
  11.   s1: TService1;
  12.   s2: TService2;
  13.   s3: TService3;
  14.   s6: TService6;
  15.   s7: TService7;
  16. begin
  17.   try
  18.     DIContainer := TDIContainer.Create;
  19.     try
  20.       // AddComponent with TClass with and   InitType = Singleton
  21.       DIContainer.AddComponent(TService1, TDIContainerInitType.Singleton);
  22.       // AddComponent with QualifiedName and InitType = Singleton
  23.       DIContainer.AddComponent('ServiceTestObjectsU.TService2',
  24.         TDIContainerInitType.Singleton);
  25.       // AddComponent with QualifiedName and InitType = CreateNewInstance
  26.       DIContainer.AddComponent('ServiceTestObjectsU.TService3',
  27.         TDIContainerInitType.CreateNewInstance);
  28.  
  29.       // GetComponent with QualifiedName
  30.       s1 := DIContainer.GetComponent('ServiceTestObjectsU.TService1')
  31.         as TService1;
  32.       s1.Message := 'I''m the first message';
  33.       WriteLn(s1.Message);
  34.  
  35.       // GetComponent with TClass
  36.       s2 := DIContainer.GetComponent(TService2) as TService2;
  37.       s2.Message := 'I''m the second message';
  38.       WriteLn(s2.Message);
  39.  
  40.       // GetComponent with a dependent service (TService3 depends upon TService1 and TService2)
  41.       s3 := DIContainer.GetComponent('ServiceTestObjectsU.TService3')
  42.         as TService3;
  43.       WriteLn(s3.GetCompoundMessage);
  44.       // s3 is not created as Singleton, so after use it I must free it
  45.       s3.Free;
  46.  
  47.       // AddComponent with QualifiedClassName, a custom initializer, an alias.
  48.       // Component will be created as singleton (single instance managed by Container)
  49.  
  50.       DIContainer.AddComponent(DIContainerUtils.GetQualifiedClassName
  51.           (TService6),
  52.           function: TObject
  53.           begin
  54.             Result := TService6.Create(DIContainer.Get(TService1) as TService1,DIContainer.Get(TService1) as TService1);
  55.           end,
  56.           'srv6',
  57.         TDIContainerInitType.Singleton);
  58.  
  59.       s6 := DIContainer.Get('srv6') as TService6;
  60.       WriteLn(s6.ToString);
  61.       s6 := DIContainer.Get('srv6') as TService6;
  62.       WriteLn(s6.ToString);
  63.  
  64.       // AddComponent with QualifiedClassName, a custom initializer, an alias.
  65.       // Component will be created as singleton (single instance managed by Container)
  66.       DIContainer.AddComponent(DIContainerUtils.GetQualifiedClassName
  67.           (TService7),
  68.             function: TObject
  69.             begin
  70.               Result := TService7.Create(DIContainer.Get(TService1) as TService1,DIContainer.Get(TService1) as TService1);
  71.             end,
  72.             'srv7intf',
  73.           TDIContainerInitType.Singleton);
  74.  
  75.       s7 := DIContainer.Get('srv7intf') as TService7;
  76.       WriteLn(s7.ToString);
  77.     finally
  78.       DIContainer.Free;
  79.     end;
  80.   except
  81.     on E: Exception do
  82.       WriteLn(E.ClassName, E.Message);
  83.   end;
  84.   readln;
  85. end.

DelphiDIContainer also handle constructor injection with automatic dependency resolution for service.

Enjoy and stay tuned.

Jan 05

News and small fixes for DataSnap Filters compendium

DataSnap Filters Compendium 4 Comments »

DataSnap Filters Compendium has been used by many users so far. I’m planning to do some change in hash filters (that do not will affect already written code) but until new version will ready I have 3 nice news about DSFC:

1. Now the project is on Google Code.

2. Franco Perana, the first contributor to the project, has fixed and optimized the LZO filter.

3. Have you used DSFC and do you want to see your application listed in the “Application Using DSFC”? If yes, leave a comment on this post with some details of your application amd I’ll add it in the proper list.

Nov 25

JSON support in Delphi2010, a simple example

CodeGear, Delphi 2010, ITDevCon2009, Programming, Uncategorized 22 Comments »

During last ITDevCon in Verona (ITALY) I talked in a session with title “Marshal and UnMarshal in Delphi 2010″ (we have published some photos about this great conference here).
In the first part of the session I’ve talked about JSON and many attendees were very interested in JSON and his application in everyday programming. I’m a real JSON fan so I decided to write this post about JSON support in Delphi2010. In my session I talked about serialization and deserialization, in this post I’ll show an example of code to do some JSON generation.

  1. program JsonTypes;
  2. {$APPTYPE CONSOLE}
  3. uses
  4.   SysUtils,
  5.   IOUtils,
  6.   DBXJSON;
  7. var
  8.   Obj, RestoredObject, JSON: TJSONObject;
  9.   arr: TJSONArray;
  10. begin
  11.   json := TJSONObject.Create;
  12.   try
  13.     WriteLn('Empty JSON Object: ' + sLineBreak,json.ToString);
  14.     json.AddPair('FirstName', TJSONString.Create('Daniele'));
  15.     WriteLn('Simple JSON Object with property: ' + sLineBreak, json.ToString);
  16.     json.AddPair(TJSONPair.Create('LastName', 'Teti'));
  17.     WriteLn('Simple JSON Object with 2 property: ' + sLineBreak, json.ToString);
  18.     arr := TJSONArray.Create;
  19.     arr.Add(9871238712);
  20.     arr.Add('peter.parker@bittime.it');
  21.     arr.Add('Via Roma, 12');
  22.     json.AddPair(TJSONPair.Create('Contacts', arr));
  23.     WriteLn('JSON Object with a property array: ' + sLineBreak, json.ToString);
  24.     obj := TJSONObject.Create;
  25.     obj.AddPair(TJSONPair.Create('John','Doe'));
  26.     json.AddPair('MyUndefinedPersonObject', obj);
  27.     WriteLn('JSON Object with a nested Object: ' + sLineBreak,json.ToString);
  28.     Write('Writing JSON object to file [jsonfile]…');
  29.     TFile.WriteAllText('jsonfile',json.ToString);
  30.     WriteLn('DONE!');
  31.     RestoredObject := TJSONObject.ParseJSONValue(
  32.       TEncoding.ASCII.GetBytes(TFile.ReadAllText('jsonfile')),0
  33.       ) as TJSONObject;
  34.     WriteLn('Readed JSON object from file: ' + sLineBreak, RestoredObject.ToString);
  35.   finally
  36.     json.Free;  //Every contained object is automatically freed
  37.   end;
  38.   readln; //If you want to see the output while in Delphi IDE
  39. end.

JSON is a lightweight data-interchange format and in Delphi 2010 you have full support for it with the built-in DBXJSON unit.
Enjoy!

Previous Entries
WP Theme & Icons by N.Design Studio
Entries RSS Comments RSS Log in